通达信KDJ底背离及选股指标（KDJ类）指标公式

买卖信号

1. **买入信号（底背离）**： - 条件TJ：L1<L2 AND K1>K2 AND REF(T,1)>3 AND T=0（价格创新低但KDJ未创新低，形成底背离） - 条件XG：CROSS(K,REF(KK,TT)) AND QT<20 AND V<REF(V,1) AND HHV(VOL,20)/VOL>2.5 AND TC<7（K线上穿近期高点，且满足成交量缩量等条件） 2. **信号输出**： - DRAWICON(XG,K,1)：XG条件满足时在K线位置显示买入图标 - DRAWTEXT(QT=0,K,'底背离')：显示"底背离"文字提示 - DRAWLINE：绘制红色和绿色趋势线辅助判断

用法

1. **适用场景**：用于捕捉KDJ指标的底背离买入机会，适用于震荡市或下跌后的反弹行情 2. **核心逻辑**：当价格创出新低但KDJ指标未创新低时，形成底背离，预示下跌动能减弱可能反转 3. **辅助条件**： - 成交量需缩量（20日内最大成交量是当前量的2.5倍以上） - QT<20且TC<7限制信号时间范围 4. **注意事项**： - 该公式包含未来函数BACKSET，使用时需注意信号漂移 - 底背离信号需结合其他技术分析方法验证 - 适用于中短线交易，优先选择日线及以上周期

公式源码

RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:SMA(RSV1,3,1);
D:SMA(K,3,1);
J:3*K-2*D,LINETHICK1;
T:=BARSLAST(L=LLV(L,10));
L1:=REF(L,T);
L2:=REF(L1,T+1);
K1:=REF(K,T);
K2:=REF(K1,T+1);
TJ:=L1<L2 AND K1>K2 AND REF(T,1)>3 AND T=0; 
TJT:=BARSLAST(TJ);
QF:=BACKSET(TJ,REF(T,1)+2);
QT:=BARSLAST(crOSS(QF=1,0.5));
KK:=IF(QF=1,K,-9999);
HH:=HHV(KK,QT);
TT:=BARSLAST(KK=HH);
TC:=QT-TJT;
XG:=CROSS(K,REF(KK,TT)) AND QT<20 AND V<REF(V,1) AND HHV(vol,20)/VOL>2.5 AND TC<7;
DRAWLINE(TT=0,K,REF(TT=0,1),REF(K,1),1),COLORGREEN;
DRAWLINE(QT=0,K,TJ,K,0),COLORRED,LINETHICK2;
DRAWICON(XG,K,1);
DRAWTEXT(QT=0,K,'底背离'),COLORYELLOW;
{
选股公式:
RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV1,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
T:=BARSLAST(L=LLV(L,10));
L1:=REF(L,T);
L2:=REF(L1,T+1);
K1:=REF(K,T);
K2:=REF(K1,T+1);
TJ:=L1<L2 AND K1>K2 AND REF(T,1)>3 AND T=0; 
TJT:=BARSLAST(TJ);
QF:=BACKSET(TJ,REF(T,1)+2);
QT:=BARSLAST(CROSS(QF=1,0.5));
KK:=IF(QF=1,K,-9999);
HH:=HHV(KK,QT);
TT:=BARSLAST(KK=HH);
TC:=QT-TJT;
XG:CROSS(K,REF(KK,TT)) AND QT<20 AND V<REF(V,1) AND HHV(VOL,20)/VOL>2.5 AND TC<7;
}