通达信2014回调买入主图指标（其他）指标公式

买卖信号

1. **突破信号**：收盘价上穿13日内最高价（高点），表示强势突破上涨 2. **回调买信号**：自定义指标"回调买"上穿0轴，表示买入时机 3. **图标信号**：回调买上穿-5时显示买入图标

用法

1. **适用场景**：适用于中短期趋势交易，重点捕捉突破买入和回调买入机会 2. **主要功能**： - 通过多条均线（5/10/20/60/120日）判断趋势方向 - 通过RSI5和ADX判断市场动量 - 突破13日高点是强势信号，可作为买入参考 - "回调买"指标结合了RSI和ADX，可用于把握回调后的买入机会 3. **注意事项**： - 该指标以买入信号为主，没有明确的卖出信号 - 突破信号可能存在假突破，需结合其他指标验证 - 建议配合成交量和其他趋势指标综合判断

公式源码

DRAWBAND(MA(CLOSE,60),RGB(200,80,80),MA(CLOSE,120),RGB(0,0,115));
MA5:MA(CLOSE,5),COLORFFFFFF;
MA10:MA(CLOSE,10),COLOR00FFFF;
MA20:MA(C,20),COLORFF00FF;
MA60:MA(CLOSE,60),COLORFF9988;
MA120:MA(CLOSE,120),COLOR0000FF;
DRAWKLINE(HIGH,OPEN,LOW,CLOSE);
BDGD:=C=HHV(C,13);
GDSJ:=BARSLAST(FILTER(crOSS(0.8,BDGD),2))+1;
高点:REF(C,GDSJ),COLORFF00FF,POINTDOT;
突破:CROSS(C,REF(高点,1)),COLOR00FFFF,POINTDOT,NODRAW;
STICKLINE(GDSJ<=6,高点,高点,3,0),COLORFF00FF;
DRAWTEXT(突破,LOW,'↑'),COLOR00FFFF;
BDDD:=C=LLV(C,13);
DDSJ:=BARSLAST(FILTER(CROSS(0.8,BDDD),2))+1;
低点:REF(C,DDSJ),COLOR00FF00,POINTDOT;
STICKLINE(DDSJ<=6,低点,低点,3,0),COLOR00FF00;
LC:=REF(CLOSE,1);
rsi5:=((SMA(MAX((CLOSE - LC),0),5,1) / SMA(Abs((CLOSE - LC)),5,1)) * 100);
TR1:=SUM(MAX(MAX((HIGH - LOW),ABS((HIGH - REF(CLOSE,1)))),ABS((LOW - REF(CLOSE,1)))),10);
HD:=(HIGH - REF(HIGH,1));
LD:=(REF(LOW,1) - LOW);
DMP:=SUM(IF(((HD > 0) AND (HD > LD)),HD,0),10);
DMM:=SUM(IF(((LD > 0) AND (LD > HD)),LD,0),10);
PDI:=((DMP * 100) / TR1);
mdi:=((DMM * 100) / TR1);
ADX:=MA(((ABS((MDI - PDI)) / (MDI + PDI)) * 100),5);
AV:=(RSI5 + ADX);
DXR:=(((ADX + REF(ADX,5)) / 2) + RSI5);
wr10:=((100 * (HHV(HIGH,10) - CLOSE)) / (HHV(HIGH,10) - LLV(LOW,10)));
NEWvol:=(RSI5 - WR10);
回调买:=(AV + NEWVOL);
DRAWTEXT(CROSS(回调买,0),L*0.95,'←回调买'),COLORYELLOW;
DRAWICON(CROSS(回调买,-5),L*0.98,1);