买卖信号

- **买入信号**： - 零下二金：MACD在零轴下方二次金叉（DIF上穿DEA且DEA<0，21日内第二次金叉） - 日底背离：DIF和DEA金叉，但股价创新低而DIF未创新低 - 金叉共振：MACD金叉的同时KDJ也出现金叉（K、D、J三条线金叉） - 柱底背离：MACD柱状图底背离（DEA<0，MACD高点降低但股价未创新高） - 积底背离：MACD绿柱面积缩小但股价创新低 - **卖出信号**： - 日顶背离：DIF和DEA死叉，但股价创新高而DIF未创新高 - 柱顶背离：MACD柱状图顶背离（DEA>0，MACD高点降低但股价创新高） - 积顶背离：MACD红柱面积缩小但股价创新高

用法

这是一个MACD指标的综合性分析公式，包含多种背离识别和信号提示。适用于： - 判断MACD金叉/死叉信号 - 识别MACD与股价的顶背离/底背离（包含柱状图背离和面积背离） - 观察MACD与KDJ的金叉共振机会 - 二次金叉信号可用于捕捉强势股回调后的再次启动 注意事项： - 背离信号需要结合成交量和股价趋势综合判断 - 零下二次金叉信号出现时需谨慎，可能处于弱势行情 - 金叉共振信号可靠性较高，但需注意KDJ的敏感性 - 公式中包含大量画线注释，实际使用时可保留或删除

公式源码

macd2:=2*(MACD.DIF-MACD.DEA);
STICKLINE(MACD2>=0 AND MACD2>REF(MACD2,1),0,MACD2,1.2,0),COLOR0000A5;
STICKLINE(MACD2>=0 AND MACD2<REF(MACD2,1),0,MACD2,1.2,0),COLORAA7800;
STICKLINE(MACD2<0 AND MACD2<REF(MACD2,1),0,MACD2,1.2,0),COLOR00A500;
STICKLINE(MACD2<0 AND MACD2>REF(MACD2,1),0,MACD2,1.2,0),COLORA500A5;
DIF:EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:EMA(DIF,9);
MACD:(DIF-DEA)*2,NODRAW;
{MACD日线二次金叉}
JCCOUNT:=COUNT(crOSS(DIF,DEA),BARSLAST(DEA>=0));
二次金叉:=CROSS(DIF,DEA) AND DEA<0 AND COUNT(JCCOUNT=2,21)=1;
DRAWTEXT(二次金叉,DEA*1.25,'零下二金'),COLORWHITE;
{MACD日线底背离}
A1:=BARSLAST(REF(CROSS(DIF,DEA),1));
底背离:=REF(CLOSE,A1+1)>CLOSE AND DIF>REF(DIF,A1+1) AND CROSS(DIF,DEA);
DRAWTEXT(底背离,DIF*0.5,'日底背'),COLORRED;
{日底背画线:DRAWLINE(A1=0,DEA,底背离,DEA,0),COLORRED,DOTLINE;}
{MACD日线顶背离}
A2:=BARSLAST(REF(CROSS(DEA,DIF),1));
顶背离:=REF(CLOSE,A2+1)<CLOSE AND REF(DIF,A2+1)>DIF AND CROSS(DEA,DIF);
DRAWTEXT(顶背离,DIF*1.12,'日顶背'),COLORGREEN;
{日顶背画线:DRAWLINE(A2=0,DEA,顶背离,DEA,0),COLORGREEN,DOTLINE;}
{MACD_kdj的金叉共振}
{DIF:EMA(CLOSE,12)-EMA(CLOSE,26);DEA:EMA(DIF,9);}
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9));
K:=SMA(RSV,9,3),NODRAW;
D:=SMA(K,9,3),NODRAW;
J:=3*K-2*D,NODRAW;
M&K金共:=CROSS(DIF,DEA) AND CROSS(K,D) AND CROSS(J,D);
DRAWTEXT(M&K金共,DEA*1.12,'金叉共振'),COLORYELLOW;
{MACD柱背离}
MACD高:=HHV(MACD,5);
C1:=BARSLAST(REF(CROSS(DEA,DIF),1));
E:=REF(C,C1+1)>C AND DEA>0 AND REF(MACD高,C1+1)<MACD高 AND CROSS(DEA,DIF) ;
DRAWTEXT(E>0,-0.5,'柱顶背'),COLORCYAN;
F:=REF(C,A1+1)>C  AND DEA<0 AND REF(MACD高,A1+1)<MACD高 AND CROSS(DIF,DEA);
DRAWTEXT(F>0,0.5,'柱底背'),COLORLIRED;
{MACD积背离}
JC:= DEA-DIF;
绿柱面积:=IF(MACD<0,SUM(MACD,BARSLAST(JC<0)),0);
红柱面积:=IF(MACD>0,SUM(MACD,BARSLAST(JC>0)),0);
本次最低价:=LLV(L,BARSLAST(JC<0));
本次最高价:=HHV(H,BARSLAST(JC>0));
X1:=IF (MACD<0,BARSLAST(CROSS(DIF,DEA)),0);
前次绿柱面积:=REF(绿柱面积,X1+1);
前次最低价:=REF(本次最低价,X1+1);
Y1:=IF((绿柱面积<0 AND Abs(绿柱面积)<ABS(前次绿柱面积) AND 本次最低价<前次最低价 ),1,0);
RS1:= MACD<0 AND REF(MACD,1)<0 AND C<前次最低价
AND ABS(绿柱面积)<ABS(前次绿柱面积) AND ABS(MACD)<ABS(REF(MACD,1));
底背驰:= IF (CROSS(DIF,DEA),REF(Y1,1),0);
DRAWTEXT(底背驰,DEA*0.8,'积底背'),COLORFF80FF;
X2:=IF (MACD>0,BARSLAST(CROSS(DEA,DIF)),0);
前次红柱面积:=REF(红柱面积,X2+1);
前次最高价:=REF(本次最高价,X2+1);
Y2:=IF((红柱面积>0 AND 红柱面积<前次红柱面积 AND 本次最高价>前次最高价 ),1,0);
RS2:= MACD>0 AND REF(MACD,1)>0 AND C>前次最高价 AND ABS(红柱面积)<ABS(前次红柱面积) AND ABS(MACD)<ABS(REF(MACD,1));
顶背驰:= IF (CROSS(DEA,DIF),REF(Y2,1),0);
DRAWTEXT(顶背驰,DEA*0.8,'积顶背'),COLORCYAN;
{
选股公式:
DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD:=(DIF-DEA)*2;
A1:=BARSLAST(REF(CROSS(DIF,DEA),1));
底背离:=REF(CLOSE,A1+1)>CLOSE AND DIF>REF(DIF,A1+1) AND CROSS(DIF,DEA);
MACD高:=HHV(MACD,5);
F:=REF(C,A1+1)>C  AND DEA<0 AND REF(MACD高,A1+1)<MACD高 AND CROSS(DIF,DEA);
柱底背:=F>0;
JC:= DEA-DIF;
绿柱面积:=IF(MACD<0,SUM(MACD,BARSLAST(JC<0)),0);
红柱面积:=IF(MACD>0,SUM(MACD,BARSLAST(JC>0)),0);
本次最低价:=LLV(L,BARSLAST(JC<0));
本次最高价:=HHV(H,BARSLAST(JC>0));
X1:=IF (MACD<0,BARSLAST(CROSS(DIF,DEA)),0);
前次绿柱面积:=REF(绿柱面积,X1+1);
前次最低价:=REF(本次最低价,X1+1);
Y1:=IF((绿柱面积<0 AND ABS(绿柱面积)<ABS(前次绿柱面积) AND 本次最低价<前次最低价 ),1,0);
RS1:= MACD<0 AND REF(MACD,1)<0 AND C<前次最低价
AND ABS(绿柱面积)<ABS(前次绿柱面积) AND ABS(MACD)<ABS(REF(MACD,1));
积底背:= IF (CROSS(DIF,DEA),REF(Y1,1),0);
三背离:底背离 AND 柱底背 AND 积底背;
}