买卖信号

**买入信号：** 1. **买入条件**（黄色图标信号）：A1至A8全部同时满足（金叉），且前一天不满足 - A1: DIFF > DEA（MACD金叉） - A2: K > D（KDJ金叉） - A3: RSI1 > RSI2（RSI金叉） - A4: LWR1 > LWR2（LWR金叉） - A5: CLOSE > BBI（价格上穿BBI） - A6: MMS > MMM（动量指标金叉） - A7: DDX1 > DDX2（DDX金叉） - A8: DLX1 > DLX2（DLX金叉） **持有信号：** - **持有条件**（粉色粗线+洋红色图标30）：A1至A8全部同时满足 **各分项金叉信号（绿色图标41）：** - MACD金叉（DIFF>DEA） - KDJ金叉（K>D） - RSI金叉（RSI1>RSI2） - LWR金叉（LWR1>LWR2） - BBI突破（CLOSE>BBI） - MMS金叉（MMS>MMM）

用法

1. **适用场景**：该指标为**多指标共振型**买入信号，要求8个不同类型的技术指标同时出现金叉才触发买入信号，属于**极强筛选型**指标 2. **使用方法**： - 当出现黄色"买入"图标时，是较为可靠的买入时机 - 出现洋红色"持有"图标时，表示所有条件持续满足，可继续持有 - 各分项绿色图标可单独观察各指标的金叉状态 3. **注意事项**： - 该指标条件极为苛刻，需要8个指标同时满足才能买入，可能错过很多行情 - 适用于追求高确定性交易机会的投资者 - 建议结合大盘环境和个股基本面综合判断 - 粉色粗线表示持有状态持续中

公式源码

N1:=3;N2:=5;N3:=8;N4:=13;
DIFF:=EMA(CLOSE,N3)-EMA(CLOSE,N4);
DEA:=EMA(DIFF,N2);
STICKLINE(CLOSE,0,1,4,1),COLORBLUE;
DRAWICON(DIFF>DEA,0.5,41);
A1:=DIFF>DEA;
RSV1:=(CLOSE-LLV(LOW,N3))/(HHV(HIGH,N3)-LLV(LOW,N3))*100;
K:=SMA(RSV1,N1,1);
D:=SMA(K,N1,1);
STICKLINE(CLOSE,1,2,4,1),COLORBLUE;
DRAWICON(K>D,1.5,41);
A2:=K>D;
LC:=REF(CLOSE,1);
rsi1:=(SMA(MAX(CLOSE-LC,0),N2,1))/(SMA(Abs(CLOSE-LC),N2,1))*100;
RSI2:=(SMA(MAX(CLOSE-LC,0),N4,1))/(SMA(ABS(CLOSE-LC),N4,1))*100;
STICKLINE(CLOSE,2,3,4,1),COLORBLUE;
DRAWICON(RSI1>RSI2,2.5,41);
A3:=RSI1>RSI2;
RSV:=-(HHV(HIGH,N4)-CLOSE)/(HHV(HIGH,N4)-LLV(LOW,N4))*100;
Lwr1:=SMA(RSV,N1,1);
LWR2:=SMA(LWR1,N1,1);
STICKLINE(CLOSE,3,4,4,1),COLORBLUE;
DRAWICON(LWR1>LWR2,3.5,41);
A4:=LWR1>LWR2;
bbi:=(MA(CLOSE,N1)+MA(CLOSE,N2)+MA(CLOSE,N3)+MA(CLOSE,N4))/4;
STICKLINE(CLOSE,4,5,4,1),COLORBLUE;
DRAWICON(CLOSE>BBI,4.5,41);
A5:=CLOSE>BBI;
mtm:=CLOSE-REF(CLOSE,1);
mms:=100*EMA(EMA(MTM,N2),N1)/EMA(EMA(ABS(MTM),N2),N1);
MMM:=100*EMA(EMA(MTM,N4),N3)/EMA(EMA(ABS(MTM),N4),N3);
STICKLINE(CLOSE,5,6,4,1),COLORBLUE;
DRAWICON(MMS>MMM,5.5,41);
A6:=MMS>MMM;
WJ:=(H+L+C)/3;
V1:=IF(H=L,1,H-MAX(O,C));
V2:=IF(H=L,1,MAX(C,O)-WJ);
V3:=IF(H=L,1,MIN(O,C)-L);
V4:=IF(H=L,1,WJ-MIN(C,O));
V5:=vol/IF(H=L,4,H-L);
V6:=(V1*V5);
V7:=(V2*V5);
V8:=(V3*V5);
V9:=(V4*V5);
买盘:=(V9+V8);
卖盘:=(V6+V7);
买卖差:=买盘-卖盘;
ddx:=买卖差;
DX:=MA(买卖差,5)*20;
DDX1:=SMA(DX,3,1);
DDX2:=SMA(DDX1,3,1);
DDX3:=(5*DDX2+4*REF(DDX2,1)+3*REF(DDX2,2)+2*REF(DDX2,3)+REF(DDX2,4))/15;
A7:=DDX1>DDX2;
量:=V; 
换手:=V/CAPITAL*100;
VAR1:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
买盘1:=IF(CLOSE>OPEN,VAR1*(HIGH-LOW),IF(CLOSE<OPEN,VAR1*((HIGH-OPEN)+(CLOSE-LOW)),VOL/2));
卖盘1:=IF(CLOSE>OPEN,0-VAR1*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE<OPEN,0-VAR1*(HIGH-LOW),0-VOL/2));
DLX:=(买盘1-(-卖盘1))/量*换手;
DLX1:=SUM(DLX,6);
DLX2:=MA(DLX1,5);
A8:=DLX1>DLX2;
买入:=A1 AND A2 AND A3 AND A4 AND A5 AND A6 =1 
AND REF(A1 AND A2 AND A3 AND A4 AND A5 AND A6 ,1)=0,COLORYELLOW;
持有:=(A1 AND A2 AND A3 AND A4 AND A5 AND A6),COLORMAGENTA,LINETHICK2;
STICKLINE(CLOSE,6,7,4,1),COLORBLUE;
DRAWICON(持有,6.5,30); 
DRAWICON(买入,6.5,28);